Logo

Letzte 100 | FORENREGELN | Impressum | News/Termine

Knowhow | Pinnwand | Archiv | Röhrendaten1 | Röhrendaten2 | RSS Feed

FORUM

Forums-Ausgangsseite

log in | registrieren

zurueck zum Forum
Board-Ansicht  Mix-Ansicht

3-Wege LSP Boxen (Small Talk: Off Topic)

verfasst von Kurt Schenk ® Homepage E-Mail, Niederrhein, 05.06.2017, 13:06

nudels93Erst mit den Thiele Small Parametern , die 78 von Gleichnamigen erforscht wurden, wurde es moeglich Boxenvolumen richtig zu berechnen.

Was vorher nur Mit einem Aufwand einer Docktorarbeit moeglich war. bevor mitte der 80er für die Hersteller, Simulationssoftwaren erhältlich waren, und für normalbürger ,in den 90ern, bezahlbar, waren, sowie Messsystheme für Schaldruck und Abstrahlwinkel.

Hallo, Reinhard,

die von dir genannte Jahreszahl "78" weicht von den damaligen Veröffentlichungen ab, die schon ein paar Jahre früher von Thiele und Small dem technischen Publikum präsentiert wurden. Siehe unten "Literaturhinweise".

Um auch für unterwegs gewappnet zu sein, wenn ich an Bastel- und Elektronikläden Ware (Frequenzweichen. Bauteile etc.) vor Ort auslieferte, schrieb ich mir ein eigenes Programm, was mit Sharps zweizeiligem "Pocket Computer PC-1475" realisiert wurde. Das kam dann (mit Farbdrucker) immer dann zum Einsatz, wenn beim Händler die Frage auftauchte, ob der Tieftöner für geschlossene oder Bassreflexgehäuse geeignet sei.

Da du uns mit deinem Beitrag regelrecht zugedeckt hast, revanchiere ich mich mit diesem Programm; zum langsamen Lesen und Abschreiben. ;-)

MfG Kurt

10 "X:SPEAKER.202": REM V2.2 Copyright (C) 1990 by Kurt Schenk: Verbessert 23.08.90
20 "A" CLS : ON ERROR GOTO 1240: CONSOLE 40: PAUSE "**LAUTSPRECHER-VOLUMEN**"
30 E$="###.##":WW$="#####.##":TT$=" ":UU$=TT$+TT$:VV$=" "
40 XX$=" ":YY$=" "
50 CLS : PAUSE "0=Ende 1=Display 2=Druck3=Eing 4=Volumen 5=Sonst"
60 IF INKEY$ ="" THEN 60
70 IF INKEY$ < CHR$ 48 OR INKEY$ > CHR$ 53 THEN 30
80 GOTO INKEY$
90 "0" CLS : CURSOR 8: WAIT 200: PRINT "**ENDE**": CLS : END
100 "3" CLS : CLEAR : DIM Y$(1)*18: CURSOR 3: PAUSE "**Daten eingeben!**"
110 CLS : PAUSE "Hersteller:": INPUT Y$(0)
120 IF LEN Y$(0)<=0 GOSUB 1250: GOTO 110
130 IF LEN Y$(0)>17 GOSUB 1260: GOTO 110
140 CLS : PAUSE "Typ:": INPUT Y$(1)
150 IF LEN Y$(1)<=0 GOSUB 1250: GOTO 140
160 IF LEN Y$(1)>17 GOSUB 1260: GOTO 140
170 CLS : PAUSE "Impedanz:": INPUT A
180 IF A<=0 OR A>16 GOSUB 1250: GOTO 170
190 CLS : PAUSE "Qt:": INPUT B
200 IF B<=0 OR B>2 GOSUB 1250: GOTO 190
210 CLS : PAUSE "VAS:": INPUT C
220 IF C<=0 OR C>2000 GOSUB 1250: GOTO 210
230 CLS : PAUSE "fs:": INPUT D
240 IF D<=0 OR D>1000 GOSUB 1250: GOTO 230
250 F=C* RCP ( SQU (1/B/ SQR 2)-1):G=D* SQR (C/F+1)
260 L=15*C*B^2.87:M=0.26*D/B^1.4:N=0.42*D/B^0.9
270 O=2.983*19*10^4/ SQU N/L-0.825*19^0.5:P=2.983*38*10^4/ SQU N/L-0.825*38^0.5: GOTO 30
280 "1" CLS : PAUSE "Display C=gschlBox F=neuB=<---- D=Reflxbox G=neu"
290 IF INKEY$ ="" THEN 290
300 IF INKEY$ < CHR$ 66 OR INKEY$ > CHR$ 71 THEN 280
310 GOTO INKEY$
320 "B" CLS : GOTO 30
330 "C" CLS : CURSOR 2: PAUSE "**Geschlossene Box**"
340 IF F=0 GOSUB 1290: GOTO 30
350 CLS : PAUSE "Volumen= "; USING WW$; MDF (F);" Literf2="; USING WW$; MDF (G);
360 PRINT " Hz Q2="; USING E$; MDF (1/ SQR 2): GOTO 280
370 "D" CLS : CURSOR 4: PAUSE "**Bassreflexbox**"
380 IF L=0 GOSUB 1290: GOTO 30
390 CLS : PAUSE "Vb="; USING WW$; MDF (L);" f3="; USING WW$; MDF (M);
400 PRINT "LT="; USING WW$; MDF (P);" fb="; USING WW$; MDF (N): GOTO 280
410 "E" CLS : GOTO 420
420 CLS : BEEP 1: CURSOR 3: PAUSE "Noch nicht fertig!": GOTO 30
430 "4" CLS : GOSUB 440: GOTO 30
440 CLS : PAUSE "Neues Volumen eingeben:": INPUT Q: PAUSE "Liter"
450 IF Q>=30 LET Y=1: RETURN
460 IF Q<30 AND Q>=6 LET Y=2: RETURN
470 IF Q<6 AND Q>=3 LET Y=3: RETURN
480 IF Q<3 GOSUB 1270: GOTO 30
490 "F" CLS : PAUSE "*Geschlossene Box (neu)*"
500 IF Q=0 GOSUB 1280: GOTO 30
510 GOSUB 990
520 CLS : PAUSE "Volumen= "; USING WW$; MDF (Q);" Literf2="; USING WW$; MDF (T);
530 PRINT " Hz Q2="; USING E$; MDF (U): GOTO 280
540 "G" CLS : PAUSE "**Bassreflexbox (neu)**"
550 IF Q=0 GOSUB 1280: GOTO 30
560 GOSUB 1000
570 CLS : PAUSE "Vb="; USING WW$; MDF (Q);" f3="; USING WW$; MDF (V);
580 PRINT "LT="; MDF (S);" R="; USING WW$; MDF (X): GOTO 280
590 "5" CLS : PAUSE "K=<---- L=FrequenzweicheM=Spez. N=Tunneloeffnung"
600 IF INKEY$ ="" THEN 600
610 IF INKEY$ < CHR$ 75 OR INKEY$ > CHR$ 78 THEN 590
620 GOTO INKEY$
630 "K" CLS : GOTO 30
640 "L" CLS : GOTO 420
650 "M" CLS : GOTO 420
660 "N" CLS : GOTO 420
670 "2" CLS : PAUSE "Druck 7=Tabl 8=Box I=neu6=<-- H=Kopf 9=Ref J=neu"
680 IF INKEY$ ="" THEN 680
690 IF INKEY$ < CHR$ 54 OR INKEY$ > CHR$ 74 THEN 670
700 GOTO INKEY$
710 "6" CLS : GOTO 30
720 "H" GOSUB 1780: GOSUB 730: GOTO 670
730 CLS : CURSOR 1: PAUSE "**Lautsprecher-Daten**";VV$;YY$;"drucken": GOSUB 1220
740 LPRINT VV$;"Gehaeuse fuer Tiefton-Lautsprecher": GOSUB 1220
750 LPRINT VV$;"Hersteller: ";TT$;Y$(0)
760 LPRINT VV$;"Typ: ";UU$;Y$(1)
770 LPRINT VV$;"Impedanz: ";TT$; USING E$;A;" Ohm"
780 GOSUB 1230
790 LPRINT VV$;"Qt:";YY$;YY$; USING WW$; MDF (B)
800 LPRINT VV$;"VAS:";XX$;YY$; USING WW$; MDF (C);" l"
810 LPRINT VV$;"fs:";YY$;YY$; USING WW$; MDF (D);" Hz"
820 GOSUB 1220: RETURN
830 "8" CLS : IF F=0 GOSUB 1290: GOTO 30
840 GOSUB 1780: CLS : CURSOR 2: PAUSE "**Geschlossene Box**";VV$;TT$;"drucken"
850 LPRINT VV$;"A. Geschlossene Box";XX$;"(nach Stark)": GOSUB 1220
860 LPRINT TT$;"Volumen (Vol):";XX$; USING WW$; MDF (F);" l"
870 LPRINT TT$;"f2: ";UU$; USING WW$; MDF (G);" Hz"
880 LPRINT TT$;"Q2: ";UU$; USING WW$; MDF (1/ SQR 2)
890 GOSUB 1230: GOTO 670
900 "9" CLS : IF L=0 GOSUB 1290: GOTO 30
910 GOSUB 1780: CLS : CURSOR 4: PAUSE "**Bassreflexbox**";YY$;YY$;"drucken"
920 LPRINT VV$;"B. Bassreflexbox";VV$;XX$;"(nach Hoge)": GOSUB 1220
930 LPRINT TT$;"Volumen (Vb):";YY$; USING WW$; MDF (L);" l"
940 LPRINT TT$;"f3: ";UU$; USING WW$; MDF (M);" Hz"
950 LPRINT TT$;"fb: ";UU$; USING WW$; MDF (N);" Hz"
960 LPRINT TT$;"Tunnel (19 qcm): "; USING WW$; MDF (O);" cm"
970 LPRINT TT$;"Tunnel (38 qcm): "; USING WW$; MDF (P);" cm"
980 GOSUB 1230: GOTO 670
990 T=D* SQR (C/Q+1):U=B* SQR (C/Q+1): RETURN
1000 V=D*(C/Q)^0.5:W=D*(C/Q)^0.32:X=20* LOG (2.6*B*(C/Q)^0.35)
1010 R=2.983*19*10^4/ SQU W/Q-0.825*19^0.5:S=2.983*38*10^4/ SQU W/Q-0.825*38^0.5: RETURN
1020 T=D* SQR (C/F+1):U=B* SQR (C/F+1): RETURN
1030 V=D*(C/L)^0.5:W=D*(C/L)^0.32:X=20* LOG (2.6*B*(C/L)^0.35)
1040 R=2.983*19*10^4/ SQU W/L-0.825*19^0.5:S=2.983*38*10^4/ SQU W/L-0.825*38^0.5: RETURN
1050 "I" CLS : IF Q=0 GOSUB 1280: GOTO 30
1060 GOSUB 1780: CLS : PAUSE "*Geschlossene Box (neu)*";VV$;XX$;"drucken"
1070 LPRINT VV$;"C. Geschlossene Box";XX$;"(nach Stark)": GOSUB 1220
1080 LPRINT TT$;"Neues Volum. (Vol):"; USING WW$; MDF (Q);" l"
1090 LPRINT TT$;"f2: ";UU$; USING WW$; MDF (T);" Hz"
1100 LPRINT TT$;"Q2: ";UU$; USING WW$; MDF (U)
1110 GOSUB 1230: GOTO 670
1120 "J" CLS : IF Q=0 GOSUB 1280: GOTO 30
1130 GOSUB 1780: CLS : PAUSE "**Bassreflexbox (neu)**";VV$;XX$;"drucken"
1140 LPRINT VV$;"D. Bassreflexbox";VV$;XX$;"(nach Hoge)": GOSUB 1220
1150 LPRINT TT$;"Neues Volumen (Vb):"; USING WW$; MDF (Q);" l"
1160 LPRINT TT$;"f3: ";UU$; USING WW$; MDF (V);" Hz"
1170 LPRINT TT$;"fb: ";UU$; USING WW$; MDF (W);" Hz"
1180 LPRINT TT$;"R: ";UU$; USING WW$; MDF (X);" dB"
1190 LPRINT TT$;"Tunnel (19 qcm): "; USING WW$; MDF (R);" cm"
1200 LPRINT TT$;"Tunnel (38 qcm): "; USING WW$; MDF (S);" cm"
1210 GOSUB 1230: GOTO 670
1220 LPRINT CHR$ &1B+"r"+"12": LF -1: GRAPH : LLINE (47,0)-(477,0),0: LTEXT : LPRINT CHR$ &0D: LPRINT CHR$ &1B+"r"+"24": RETURN
1230 LPRINT CHR$ &1B+"r"+"12": LF -1: GRAPH : LLINE (47,0)-(477,0),3: LTEXT : LPRINT CHR$ &0D: LPRINT CHR$ &1B+"r"+"24": RETURN
1240 CLS : BEEP 1: CURSOR 7: PAUSE "**Fehler!**": GOTO 30
1250 CLS : BEEP 1: CURSOR 3: PAUSE "**Nicht korrekt!**": RETURN
1260 CLS : BEEP 1: CURSOR 2: PAUSE "**Ausdruck zu lang!**": RETURN
1270 CLS : BEEP 1: CURSOR 2: PAUSE "**Volumen zu klein!**": RETURN
1280 CLS : BEEP 1: PAUSE "Neues Volumen eingeben!": RETURN
1290 CLS : BEEP 1: PAUSE "Herstellerdaten eingeben": RETURN
1300 "7" CLS : PAUSE "Tabelle A=gschlBox D=neuC=<---- B=Reflxbox E=neu"
1310 IF INKEY$ ="" THEN 1310
1320 IF INKEY$ < CHR$ 65 OR INKEY$ > CHR$ 69 THEN 1300
1330 IF INKEY$ = CHR$ 65 THEN 1730
1340 IF INKEY$ = CHR$ 66 THEN 1530
1350 IF INKEY$ = CHR$ 67 THEN 670
1360 IF INKEY$ = CHR$ 68 THEN 1580
1370 IF INKEY$ = CHR$ 69 THEN 1380
1380 CLS : IF Q=0 GOSUB 1280: GOTO 30
1390 GOSUB 1780: GOSUB 1400: GOTO 1440
1400 CLS : CURSOR 4: PAUSE "**Bassreflexbox**": PAUSE "Volumen-Auswahl drucken"
1410 LPRINT VV$;"F. Bassreflexbox";VV$;XX$;"(nach Hoge)": GOSUB 1230
1420 LPRINT VV$;"Volumen Frequ. Druck Tunnel (cm)"
1430 LPRINT VV$;"Vb (l) f3(Hz) R(dB) 19qcm 38qcm": GOSUB 1230: RETURN
1440 ON Y GOTO 1450,1490,1510
1450 GOSUB 1460:Q=Q-30: GOSUB 1220: GOTO 1300
1460 FOR Q=Q-25 TO Q+50 STEP 5: GOSUB 1000
1470 LPRINT " "; USING WW$; MDF (Q); USING WW$; MDF (V);" "; USING E$; MDF (X);" "; USING E$; MDF (R); USING E$; MDF (S)
1480 NEXT Q: RETURN
1490 GOSUB 1500:Q=Q-6: GOSUB 1220: GOTO 1300
1500 FOR Q=Q-5 TO Q+10: GOSUB 1000: GOTO 1470
1510 GOSUB 1520:Q=Q-3: GOSUB 1220: GOTO 1300
1520 FOR Q=Q-2.5 TO Q+5 STEP 0.5: GOSUB 1000: GOTO 1470
1530 IF L=0 GOSUB 1290: GOTO 30
1540 GOSUB 1780: GOSUB 1400
1550 FOR L=L-5 TO L+10: GOSUB 1030
1560 LPRINT " "; USING WW$; MDF (L); USING WW$; MDF (V);" "; USING E$; MDF (X);" "; USING E$; MDF (R); USING E$; MDF (S)
1570 NEXT L:L=L-6: GOSUB 1220: GOTO 1300
1580 IF Q=0 GOSUB 1280: GOTO 30
1590 GOSUB 1780: GOSUB 1600: GOTO 1640
1600 CLS : CURSOR 2: PAUSE "**Geschlossene Box**": PAUSE "Volumen-Auswahl drucken"
1610 LPRINT VV$;"E. Geschlossene Box";XX$;"(nach Stark)": GOSUB 1230
1620 LPRINT VV$;"Volumen";XX$;"Reson.Frequ.";VV$;"Q-Faktor"
1630 LPRINT VV$;"Vol (l)";TT$;"f2 (Hz) ";TT$;"Q2": GOSUB 1230: RETURN
1640 ON Y GOTO 1650,1690,1710
1650 GOSUB 1660:Q=Q-30: GOSUB 1220: GOTO 1300
1660 FOR Q=Q-25 TO Q+50 STEP 5: GOSUB 990
1670 LPRINT " "; USING WW$; MDF (Q);YY$; USING WW$; MDF (T);VV$; USING WW$; MDF (U)
1680 NEXT Q: RETURN
1690 GOSUB 1700:Q=Q-6: GOSUB 1220: GOTO 1300
1700 FOR Q=Q-5 TO Q+10: GOSUB 990: GOTO 1670
1710 GOSUB 1720:Q=Q-3: GOSUB 1220: GOTO 1300
1720 FOR Q=Q-2.5 TO Q+5 STEP 0.5: GOSUB 990: GOTO 1670
1730 IF F=0 GOSUB 1290: GOTO 30
1740 GOSUB 1780: GOSUB 1600
1750 FOR F=F-5 TO F+10: GOSUB 1020
1760 LPRINT " "; USING WW$; MDF (F);YY$; USING WW$; MDF (T);VV$; USING WW$; MDF (U)
1770 NEXT F:F=F-6: GOSUB 1220: GOTO 1300
1780 GOSUB 1790: ON Z GOSUB 1870,1880,1890,1900: RETURN
1790 CLS : PAUSE "Farbe: 1=schwarz 2=rot 3=<--- 4=violett 5=blau"
1800 IF INKEY$ ="" THEN 1800
1810 IF INKEY$ < CHR$ 49 OR INKEY$ > CHR$ 53 THEN 1790
1820 IF INKEY$ = CHR$ 49 LET Z=1
1830 IF INKEY$ = CHR$ 50 LET Z=2
1840 IF INKEY$ = CHR$ 51 THEN 30
1850 IF INKEY$ = CHR$ 52 LET Z=3
1860 IF INKEY$ = CHR$ 53 LET Z=4
1870 COLOR 0,7: RETURN
1880 COLOR 3,7: RETURN
1890 COLOR 1,7: RETURN
1900 COLOR 5,7: RETURN
1910 END

[image] [image]
[image]

---
Weniger trinken, weniger rauchen,
öfter mal ein Büchlein kaufen!

 

gesamter Thread:

zurueck zum Forum
Board-Ansicht  Mix-Ansicht
158143 Postings in 14387 Threads, 2618 registrierte User, 267 User online (4 reg., 263 Gäste)
FORUM | Kontakt
RSS Feed
powered by my little forum